Before proceeding, rename the various menu choices by clicking on each and setting its Name property in the Properties window. For example, click on Employees → Show All and set its name to mnuEmployeesShowAll, and set its Find sub-menu to mnuEmployeeFind, as shown in Figure 3-1.

Figure 3-1. Set the menu choice name in the Properties window

Setting the event handlers for the menu choices is also pretty easy, as you want them to do the same thing their related buttons specify. Thus, click on the All Employees button, and in the Properties window, click the Events button (the lightning bolt) to see the names of the predefined event handlers for this control. Copy the button’s Click event handler (btnAllClick).

Now click on the Employees menu to open it, and select Show All. In the Properties window, click on the Event button (the one with the lightning bolt) to reveal the events for this menu choice, and in the Click event, paste the btnAllClick event handler name, as shown in Figure 3-2.

Figure 3-2. Setting the Click event handler

Do the same for the Show All for each of the other menu choices. Next, click on the Find button for Customers, and pick up btnFind_Click, which you can add to the Find menu choices for Customers and Suppliers.

Before you choose the Show All menu choice, you’ll need to make some changes to the btnAllClick menu choice, because that event handler, as written, assumes it was clicked by a Button control. The modified event handler for the All buttons on the Welcome page is shown in Example 3-1.

Private Sub btnAllClick( _
ByVal sender As System.Object, _
ByVal e As System.EventArgs) _
Handles btnAllCustomers.Click, _
btnAllSuppliers.Click, _
btnAllEmployees.Click, _
btnAllOrders.Click, _
mnuEmployeeShowAll.Click, _
ShowAllToolStripMenuItem1.Click, _
ShowAllToolStripMenuItem2.Click, _
ShowAllToolStripMenuItem3.Click
    MessageBox.Show(CType(sender, Button).Text + _
    " not yet implemented", "Not Yet Implemented", _
        MessageBoxButtons.OK, MessageBoxIcon.Exclamation)
End Sub

Because a ToolStripMenuItem does not inherit from Control, you’ll need to test the type of the sender and then cast accordingly. Thus, replace the body of Example 3-1 with the code shown in Example 3-2.

Dim txt As String = String.Empty

If TypeOf sender Is Button Then
    txt = CType(sender, Button).Text
ElseIf TypeOf sender Is ToolStripMenuItem Then
    txt = CType(sender, ToolStripMenuItem).Text
End If

MessageBox.Show(txt + _
" not yet implemented", "Not Yet Implemented", _
    MessageBoxButtons.OK, MessageBoxIcon.Exclamation)

Before we continue with this application, let’s explore some other cool controls that don’t quite fit with our immediate business requirements but are still very handy. To get started, you’ll add a Web Browser menu command and, in fact, you’ll make it the first menu item. No problem, click on the end of the menu bar and choose the smart tab’s Edit Items... link. This opens the Items Collection Editor. You have the opportunity to edit the names of the items and to insert a new item by clicking the Add button, as shown in Figure 3-3.

Figure 3-3. Adding menu items

Add a new menu item and rename it mnuWebBrowser. Set its Text to Web Browser. Click the Up button to raise it to the first position in the menu and click OK. Set the event handler for the Click event of this menu item, as shown in Example 3-3.

Private Sub mnuWebBrowser_Click( _
   ByVal sender As System.Object, _
   ByVal e As System.EventArgs) Handles mnuWebBrowser.Click
   frmWeb.Show()
End Sub

It would be useful to disable the Previous button when it is not possible to go back any further, and to disable the Next button when there is no next page. The Web Browser has two properties (CanGoBack and CanGoForward ) that you can test. Rather than testing these every time the form is navigated, it’s more efficient to respond to the events that fire when these properties change—CanGoBackChanged and CanGoForwardChanged—as shown in Example 3-4.

Private Sub WebBrowser1_CanGoBackChanged( _
ByVal sender As System.Object, _
ByVal e As System.EventArgs) Handles WebBrowser1.CanGoBackChanged
   btnPrevious.Enabled = WebBrowser1.CanGoBack
End Sub

Private Sub WebBrowser1_CanGoForwardChanged( _
ByVal sender As System.Object, _
ByVal e As System.EventArgs) Handles WebBrowser1.CanGoForwardChanged
   btnNext.Enabled = WebBrowser1.CanGoForward
End Sub

In addition, you’ll handle the Navigating event from the browser to set the cursor to a Wait cursor while the page is loading (see Example 3-5).

Private Sub WebBrowser1_Navigating( _
ByVal sender As System.Object, _
ByVal e As System.Windows.Forms.WebBrowserNavigatingEventArgs) _
Handles WebBrowser1.Navigating
    Me.Cursor = Cursors.WaitCursor
End Sub

Finally, you’ll handle the Navigated event, which fires once the new page is loaded, as shown in Example 3-6.

Private Sub WebBrowser1_Navigated( _
ByVal sender As System.Object, _
ByVal e As System.Windows.Forms.WebBrowserNavigatedEventArgs) _
Handles WebBrowser1.Navigated
    Me.txtURL.Text = Me.WebBrowser1.Url.ToString()
    Me.Cursor = Cursors.Default
End Sub

As you can see, once the page is loaded, you load its URL into txtURL and you reset the cursor to the default. You change the URL in the Navigated event in case the user has navigated through hyperlinks (so that the text box is kept up to date).

There are a number of ways to set the initial URL for the browser. You can set the URL property of the browser, or you can set the initial URL programmatically. You’ll choose the latter, because you want to use the same address for the Home button. To make this work, you’ll add a constant member of the frmWeb class that was declared for you by Visual Studio 2005 in the code file for the form:

Const home As String = "http://www.libertyassociates.com"

Next, navigate to that location in the form’s Load event handler, as shown in Example 3-7.

Private Sub frmWeb_Load( _
 ByVal sender As System.Object, _
 ByVal e As System.EventArgs) _
 Handles MyBase.Load
     Me.WebBrowser1.Navigate(home)
     Me.btnNext.Enabled = False
     Me.btnPrev.Enabled = False
 End Sub

The bold code, which calls the Navigate() method on the WebBrowser control, causes the web browser to open to the home page (and to disable the Next and Previous buttons), as shown in Figure 3-6.

Figure 3-6. Web browser home page

A number of event handlers will all do the same thing: tell the web browser to navigate to whatever URL is in the text box. So factor that logic out to a helper method of the frmWeb class, as shown in Example 3-8.

Private Sub GoToURL()
    If Not Me.txtURL.Text.Equals("") Then
        Me.WebBrowser1.Navigate(Me.txtURL.Text)
    End If
End Sub

Notice that if the URL text is blank, the method does nothing, but if the user navigates to a new page, that new page is shown in the text box.

If the user enters a URL in the text box and then hits tab (to leave the URL text box), you’ll want to invoke the GoToURL method. The same logic will apply if the user presses the Go button, so you’ll want to handle both events in the Leave event handler shown in Example 3-9.

Private Sub TextBox1_Leave( _
ByVal sender As System.Object, _
ByVal e As System.EventArgs) _
Handles txtURL.Leave, btnGo.Click
    GoToURL()
End Sub

Finally, if the user enters a URL and presses the Enter key, you’ll want to take that as a signal to go to the URL as well. To do so, you’ll examine each key pressed in the TextBox to see if it is the enter key in the KeyUp event handler shown in Example 3-10.

Private Sub TextBox1_KeyUp( _
ByVal sender As System.Object, _
ByVal e As System.Windows.Forms.KeyEventArgs) Handles txtURL.KeyUp
    If e.KeyCode = Keys.Enter Then
        GoToURL()
    End If
End Sub

The text box should display all the URLs that match the text you’ve begun to type (this is how Internet Explorer behaves, why not you?) That turns out to be easy, thanks to two properties of the text box control: AutoCompleteMode and AutoCompleteSource, as shown in Figure 3-7.

Figure 3-7. Text box properties

The AutoCompleteMode may be Suggest, Append, or SuggestAppend (or none). Suggest provides a drop down (see Figure 3-8), Append attempts to complete the listing for you. Whatever mode you choose, you must also tell the text box where to get the data to use to try to complete your entry. Your choices are shown in Figure 3-7. For this example, select Suggest for AutoCompleteMode, and AllUrl for AutoCompleteSource. As the user enters text, the auto-complete box provides suggested matches, as shown in Figure 3-8

Figure 3-8. Text box with URL history

Clicking on a choice in the text box causes the browser to navigate to the selected page, as shown in Figure 3-9.^[*]

As the user follows links, the txtURL text box is updated and the Next and Previous buttons will be enabled or disabled as appropriate. The WebBrowser control keeps track of its own history, so implementing the Next and Previous buttons’ event handlers is fairly trivial, as shown in Example 3-11.

Figure 3-9. Using buttons and events in browsing

Private Sub btnPrev_Click( _
ByVal sender As System.Object, _
ByVal e As System.EventArgs) _
Handles btnPrev.Click
    Me.WebBrowser1.GoBack()
End Sub

Private Sub btnNext_Click( _
ByVal sender As System.Object, _
ByVal e As System.EventArgs) _
Handles btnNext.Click
    Me.WebBrowser1.GoForward()
End Sub

You can now navigate from page to page, and move back and forth through the pages you’ve seen. Finally, the browser has a method GoHome that takes you to the URL marked as Home in Internet Explorer. Example 3-12 shows the implementation for the Home button Click event.

Private Sub btnHome_Click( _
ByVal sender As System.Object, _
ByVal e As System.EventArgs) Handles btnHome.Click
   Me.WebBrowser1.GoHome()
End Sub

One very powerful reason for having a web browser built into your application is to enable users to XML documents. The web browser automatically understands the hierarchical structure of such documents.

To see an XML document in your browser, you can locate the document in Windows Explorer and then just drag and drop it onto the Web Browser control (as shown in the circled area in Figure 3-10). When you drop the document in the browser, it is displayed and the Navigated event fires. As shown earlier, this causes the URL of the XML document to appear in the text box above the browser, as shown in Figure 3-10.

Figure 3-10. Viewing XML documents

What you want, however, is a MaskedTextBox that is bound to your data. There are many ways to accomplish this, but the easiest is to drag one from the Suppliers table.

Delete the MaskedTextBox on your form and its associated label, and open the Data Source View (Data → Show Data Sources). Expand the Suppliers table and click on the drop down next to phone. Click on Customize. This opens the Options Dialog, as shown in Figure 3-12.

Figure 3-12. Options dialog for customizing data controls

In the left window, pick Windows Forms Designer and under that Data UI Customization. The Associated Controls window will show the default list of controls associated with the Data type String. Check MaskedTextBox.

You may click Set Default if you want this control to be available in the list for other controls that manage strings. In either case, click OK. Return to the Phone field and drop down the list of controls and choose Masked Text Box. You can now drag the MaskedTextBox onto your form, align its label, and then click on its smart tag to choose the mask you want.

You will have to change your code slightly to enable and disable the MaskedTextBox and to set up its event handler. In the Load method handler for the form, add a variable to hold the MaskedTextBox immediately following the definition of the txtbox variable in the existing code, like this:

Dim txtbox As TextBox = Nothing
Dim masked As MaskedTextBox = Nothing

In the For Each loop of the same method, add an if statement for MaskedTextBox, just as you have for TextBox, as shown in Example 3-13.

For Each ctrl In Me.Controls
   If TypeOf ctrl Is MaskedTextBox Then
      masked = CType(ctrl, MaskedTextBox)
      masked.Enabled = False
      AddHandler masked.TextChanged, AddressOf TextBoxChanged
   ElseIf TypeOf ctrl Is TextBox Then
      txtbox = CType(ctrl, TextBox)
      txtbox.Enabled = False
      AddHandler txtbox.ModifiedChanged, AddressOf TextBoxChanged
   ElseIf TypeOf ctrl Is DataGridView Then
      dgv = CType(ctrl, DataGridView)
      dgv.Enabled = False
      AddHandler dgv.CellValueChanged, AddressOf DataGridChanged
   End If
Next

Notice that the event you will handle (TextChanged) is different from the event you handle for TextBox (ModifiedChanged), but you will share event handlers nonetheless.

Modify StopEditing to test for the MaskedTextBox type as well, as shown in Example 3-14.

Private Sub StopEditing()
    Dim ctrl As Control
    For Each ctrl In Me.Controls
        If TypeOf ctrl Is DataGridView _
        Or TypeOf ctrl Is TextBox _
        Or TypeOf ctrl Is MaskedTextBox Then
            ctrl.Enabled = False
        End If
    Next
    Me.Text = formName + " Read only"
End Sub

You’re all set. When you run the program, the phone number is now in the mask. If you enter edit mode, you will not be able to enter illegitimate characters into the phone number and the mask will indicate the area code and the number of digits expected, as shown in Figure 3-13.

Figure 3-13. Input mask

The print Click event handler is a bit more complicated. You will break the logic into two methods: the event handler for the menu choice, and the event handler for the PrintDocument object you’ve added to your page. Because you will need to create the Stream object for the document in the Print event handler, and you’ll need to reference that stream in the PrintDocument’s PrintPage event handler, you’ll create a member variable for the class to hold that stream.

Public Class frmText
    Private streamToPrint As StringReader

To identify the string reader, you’ll add the following to the top of the file:

Imports System.IO

When the user clicks on the Print menu choice, the event handler initializes streamToPrint by creating a new StringReader with the text from the RichTextBox:

streamToPrint = New StringReader(Me.RichTextBox1.Text)

The PrintDialog is shown, allowing the user to pick a printer and set its characteristics:

Me.PrintDialog1.Document = PrintDocument1
Dim dlgResult As DialogResult = Me.PrintDialog1.ShowDialog()

If the user clicks OK, the PrintDocument’s Print method is called, which raises the PrintPage event on that object, as shown in Example 3-18.

If dlgResult = Windows.Forms.DialogResult.OK Then
   Try
      PrintDocument1.Print()
   Catch ex As Exception
      MessageBox.Show("error printing " + ex.Message)
   Finally
      streamToPrint.Close()
   End Try
End If

When the PrintPage event is raised, the PrintDocument’s event handler is called, as shown in Example 3-19.

' called from mnuFilePrint_Click
Private Sub PrintDocument1_PrintPage( _
ByVal sender As System.Object, _
ByVal e As System.Drawing.Printing.PrintPageEventArgs) _
Handles PrintDocument1.PrintPage

   Dim printFont As Font = New Font("Verdana", 10)

   Dim linesPerPage As Single = 0
   Dim yPosition As Single = 0
   Dim ctr As Integer = 0
   Dim left As Single = e.MarginBounds.Left
   Dim top As Single = e.MarginBounds.Top
   Dim line As String = Nothing

   ' Calculate the number of lines per page.
   linesPerPage = e.MarginBounds.Height / _
       printFont.GetHeight(e.Graphics)

   While ctr < linesPerPage
      line = streamToPrint.ReadLine()
      If line Is Nothing Then
         Exit While
      End If
      yPosition = top + ctr * _
          printFont.GetHeight(e.Graphics)

      e.Graphics.DrawString 
( _
      line, _
      printFont, _
      Brushes.Black, _
      left, _
      yPosition, _
      New StringFormat())

      ctr += 1
   End While

   If line IsNot Nothing Then
      e.HasMorePages = True
   Else
      e.HasMorePages = False
   End If

End Sub

The second argument passed in is of type PrintPageEventArgs, which contains vital information about how to print the page.

For simplicity you’ll hardcode a font (Verdana, 10 point) to print with, using the following declaration:

Dim printFont As Font = New Font("Verdana", 10)

With that font in hand, you can compute the number of lines per page:

linesPerPage = e.MarginBounds.Height / _
    printFont.GetHeight(e.Graphics)

That done, you can begin reading lines from the stream. As long as you have a valid line, you can compute its position on the page, then call the DrawString method on the Graphics object you get from the PrintPageEventArgs parameter, e.

This method is overloaded. The version you’ll use takes six parameters, as shown in Example 3-20.

yPosition = top + ctr * _
    printFont.GetHeight(e.Graphics)

printPageEventArgs.Graphics.DrawString( _
line, _
printFont, _
Brushes.Black, _
left, _
yPosition, _
New StringFormat())

In Example 3-20:

The two TreeView controls work identically, except that the left control, tvwSource, lists the directories and files, whereas the right control, tvwTarget, lists only directories. Also, although tvwSource will allow multiselect, which is the default for TreeView controls, you will enforce single selection for tvwTarget.

Before you begin, please add these three Imports statements to the top of your code file:

Imports System.Collections.Generic
Imports System.Collections
Imports System.IO

Factor the common code for both TreeView controls into a shared method FillDirectoryTree , passing in the target tree view and a flag indicating whether to get the files, as shown in Example 3-22.

Private Sub FillDirectoryTree( _
ByVal tvw As TreeView, _
ByVal getFiles As Boolean)

End Sub

You’ll call this method from the Form’s Load event handler, once for each of the two controls, as shown in Example 3-23.

Private Sub frmFilesCopier_Load( _
ByVal sender As System.Object, _
ByVal e As System.EventArgs) Handles MyBase.Load

      Me.Cursor = Cursors.WaitCursor
      Me.FillDirectoryTree(Me.tvwSource, True)
      Me.FillDirectoryTree(Me.tvwTarget, False)
      Me.Cursor = Cursors.Default
 End Sub

tvw.Nodes.Clear()

GetSubDirectoryNodes(subNode, _
 dirsub.FullName, getFileNames, level + 1)

Private Const MaxLevel As Integer = 2
If level < MaxLevel Then

Before calling GetSubDirectoryNodes, FillDirectoryTree needs to get all the logical drives on the system. To do so, call a shared method of the Environment object, GetLogicalDrives. The Environment class provides information about and access to the current platform environment. You can use the Environment object to get the

Figure 3-16. Recursion

machine name, OS version, system directory, and so forth, from the computer on which you are running your program.

Dim strDrives As String() = Environment.GetLogicalDrives()

GetLogicalDrives returns an array of strings, each of which represents the root directory of one of the logical drives. You will iterate over that collection, adding nodes to the TreeView control as you go.

For Each rootDirectoryName As String In strDrives

You process each drive within the For Each loop.

The very first thing you need to determine is whether the drive is ready. One hack for doing that is to get the list of top-level directories from the drive by calling GetDirectories on a DirectoryInfo object you create for the root directory, like this:

Try
    Dim dir As DirectoryInfo = New DirectoryInfo(rootDirectoryName)
    dir.GetDirectories()

The DirectoryInfo class exposes instance methods for creating, moving, and enumerating through directories, their files, and their subdirectories. The GetDirectories method throws an exception if the drive is not ready (e.g., the A: drive does not have a floppy in it). Your goal here is just to skip over those drives; you don’t actually care about the directories returned.

Wrap the call in a try block and take no action in the catch block. The effect is that if an exception is thrown, the drive is skipped.

Continuing in the try block (if you’re still there, the drive is ready), create a TreeNode to hold the root directory of the drive and add that node to the TreeView control, like this:

Dim ndRoot As TreeNode = New TreeNode(rootDirectoryName)
tvw.Nodes.Add(ndRoot)

To get the plus signs right in the TreeView, you must find at least two levels of directories (so the TreeView knows which directories have subdirectories and can write the plus sign next to them). You do not want to recurse through all the subdirectories, however, because that would be too slow.

The job of the GetSubDirectoryNodes method is to recurse two levels deep, as shown schematically in Figure 3-16. You pass it:

Here’s the code for doing these steps:

If (getFiles = True) Then
    GetSubDirectoryNodes(ndRoot, ndRoot.Text, True, 1)
Else
    GetSubDirectoryNodes(ndRoot, ndRoot.Text, False, 1)
End If

You will see why you need to pass in ndRoot.Text when you recurse back into GetSubDirectoryNodes.

Private Sub GetSubDirectoryNodes( _
ByVal parentNode As TreeNode, _
ByVal fullName As String, _
ByVal getFileNames As Boolean, _
ByVal level As Int32)

    Dim dir As DirectoryInfo = New DirectoryInfo(fullName)

Try
    Dim dirSubs As DirectoryInfo() = dir.GetDirectories()
    For Each dirsub As DirectoryInfo In dirSubs
    ''...
Catch ex As Exception
    ' ignore exceptions
End Try

Dim subNode As TreeNode = New TreeNode(dirsub.Name)
parentNode.Nodes.Add(subNode)

Private Const MaxLevel As Integer = 2

If level < MaxLevel Then
    'recursion
    GetSubDirectoryNodes( _
        subNode, _
        dirsub.FullName, _
        getFileNames, _
        level + 1)
End If

If getFileNames = True Then
    Dim files As FileInfo() = dir.GetFiles()

For Each file As FileInfo In files
    Dim fileNode As TreeNode = New TreeNode(file.Name)
    parentNode.Nodes.Add(fileNode)
Next

You must handle a number of events for this page to work properly. For example, the user might click Cancel, Copy, Clear, or Delete. She might click one of the checkboxes in the left TreeView, one of the nodes in the right TreeView, or one of the plus signs in either view.

Let’s consider the clicks on the TreeViews first, as they are the most interesting, and potentially the most challenging.

Private Sub tvwSource_AfterCheck( _
ByVal sender As System.Object, _
ByVal e As System.Windows.Forms.TreeViewEventArgs) _
Handles tvwSource.AfterCheck
    SetCheck 
(e.Node, e.Node.Checked)
End Sub

Private Sub SetCheck( _
ByVal node As TreeNode, _
ByVal check As Boolean)
    For Each n As TreeNode In node.Nodes
        n.Checked = check
        If n.Nodes.Count <> 0 Then
            SetCheck(n, check)
        End If
    Next
End Sub

Private Sub tvwExpand( _
ByVal sender As System.Object, _
ByVal e As System.Windows.Forms.TreeViewCancelEventArgs) _
Handles tvwSource.BeforeExpand, tvwTarget.BeforeExpand
    Dim tvw As TreeView = CType(sender, TreeView)
    Dim getFiles As Boolean = (tvw.Name = "tvwSource")
    Dim currentNode As TreeNode = e.Node
    Dim fullName As String = currentNode.FullPath
    currentNode.Nodes.Clear()
    GetSubDirectoryNodes(currentNode, fullName, getFiles, 1)
End Sub

Dim getFiles As Boolean = False
If tvw.Name = "tvwSource" Then
   getFiles = True
End If

Dim currentNode As TreeNode = e.Node

currentNode.Nodes.Clear()

Private Sub tvwTarget_AfterSelect( _
ByVal sender As System.Object, _
ByVal e As System.Windows.Forms.TreeViewEventArgs) _
Handles tvwTarget.AfterSelect
    Dim theFullPath As String = GetParentString 
(e.Node)

If theFullPath.EndsWith("") Then
    theFullPath = theFullPath.Substring(0, theFullPath.Length − 1)
End If
Me.txtTarget.Text = theFullPath

Private Function GetParentString(ByVal node As TreeNode) As String
    If node.Parent Is Nothing Then
        Return node.Text
    Else
        Dim endString As String = String.Empty
        If node.Nodes.Count <> 0 Then endString = ""
        Return GetParentString(node.Parent) + node.Text + endString
    End If
End Function

Private Sub btnClear_Click( _
ByVal sender As System.Object, _
ByVal e As System.EventArgs) _
Handles btnClear.Click
    For Each node As TreeNode In tvwSource.Nodes
        SetCheck(node, False)
    Next
End Sub

Now that you can check the files and pick the target directory, you’re ready to handle the Copy button’s Click event. The very first thing you need to do is to get a list of which files were selected. This will be represented as a collection of FileInfo objects. Delegate responsibility for filling the list to a method called GetFileList as the first step executed by the event handler:

Private Sub btnCopy_Click( _
ByVal sender As System.Object, _
ByVal e As System.EventArgs) _
Handles btnCopy.Click
    Dim fileList As List(Of FileInfo) = GetFileList()

Let’s examine the GetFileList method before returning to the event handler.

Private Function GetFileList() As List(Of FileInfo)
    Dim fileNames As List(Of String) = New List(Of String)

For Each theNode As TreeNode In tvwSource.Nodes
    GetCheckedFiles 
(theNode, fileNames)
Next

Private Sub GetCheckedFiles( _
ByVal node As TreeNode, _
ByVal fileNames As List(Of String))
    If node.Nodes.Count = 0 Then
        If node.Checked Then
            fileNames.Add(GetParentString(node))
        End If
    Else
        For Each n As TreeNode In node.Nodes
            GetCheckedFiles(n, fileNames)
        Next
    End If

End Sub

Dim fileList As List(Of FileInfo) = New List(Of FileInfo)

For Each fileName As String In fileNames
    Dim file As FileInfo = New FileInfo(fileName)
    If file.Exists Then
        fileList.Add(file)
    End If
Next

Return fileList

Private Sub btnCopy_Click( _
ByVal sender As System.Object, _
ByVal e As System.EventArgs) Handles btnCopy.Click

    Dim fileList As List(Of FileInfo) = GetFileList()

    For Each file As FileInfo In fileList
        Try
            lblStatus.Text = "Copying " + txtTarget.Text + "" + file.Name + "..."
            Application.DoEvents()
            file.CopyTo(txtTarget.Text + "" + file.Name, cbOverwrite.Checked)
        Catch ex As Exception
            MessageBox.Show(ex.Message)
        End Try
    Next
    lblStatus.Text = "Done"
    Application.DoEvents()
End Sub

The code to handle the delete event is even simpler. The very first thing you do is make sure the user really wants to delete the files. You can use the MessageBox static Show method, passing in the message you want to display, the title "Delete Files" as a string, and flags:

When the user chooses Yes or No, the result is passed back as a System.Windows.Forms.DialogResult enumerated value. You can test this value to see if the user selected Yes, as shown in the following code snippet:

Private Sub btnDelete_Click( _
   ByVal sender As System.Object, _
   ByVal e As System.EventArgs) Handles btnDelete.Click
    Dim result As DialogResult = _
        MessageBox.Show( _
            "Are you quite sure?", _
            "Delete Files", _
            MessageBoxButtons.YesNo, _
            MessageBoxIcon.Exclamation, _
            MessageBoxDefaultButton.Button2)
    If result = Windows.Forms.DialogResult.Yes Then
        Dim fileNames As List(Of FileInfo) = GetFileList()
        For Each file As FileInfo In fileNames
            Try
                lblStatus.Text = "Deleting " + txtTarget.Text + "" +
                file.Name + "..."
                Application.DoEvents()
                file.Delete()
            Catch ex As Exception
                MessageBox.Show(ex.Message)
            End Try
        Next
        lblStatus.Text = "Done."
        Application.DoEvents()
    End If
End Sub

Assuming the value you get back from the DialogResult is Yes, you get the list of fileNames and iterate through it, deleting each as you go:

The final working version of FilesCopier window is shown in Figure 3-17.

Figure 3-17. Working version of the FilesCopier