The Model

Managing the items of the invoice is part of the business logic and, thus, is the duty of the Model. Therefore, we need procedures to add an item to the invoice, to delete items, to retrieve the number of the items in an invoice, and to calculate the total amount of the invoice.

1. Add the following code in the IInvoiceModelInterface declaration in the Model.Interfaces unit.

     IInvoiceModelInterface = interface
       ...
       procedure AddInvoiceItem(const itemDescription: string; const quantity: integer);
       procedure GetInvoiceItems (var itemsList: TObjectList<TInvoiceItem>);
       procedure DeleteAllInvoiceItems;
       procedure CalculateInvoiceAmounts;
       function GetInvoiceRunningBalance:Currency;
       function GetNumberOfInvoiceItems: integer;
       property InvoiceRunningBalance: Currency read GetInvoiceRunningBalance;
       property NumberOfInvoiceItems: integer read GetNumberOfInvoiceItems;
    end;

2. Develop the code in the Model.Invoice unit.

   type
     TInvoiceModel = class (TInterfacedObject, IInvoiceModelInterface)
     private
       ...
       fRunningBalance: Currency;
       function GetInvoiceRunningBalance:Currency;
       function GetNumberOfInvoiceItems: integer;
     public
       ...
       procedure AddInvoiceItem(const itemDescription: string; const quantity: integer);
       procedure GetInvoiceItems (var itemsList: TObjectList<TInvoiceItem>);
       procedure GetInvoiceItemFromID (const itemID: Integer; var item: TItem);
       procedure DeleteAllInvoiceItems;
       procedure CalculateInvoiceAmounts;
    end;
   
   ...
   
   procedure TInvoiceModel.AddInvoiceItem(const itemDescription: string; const quantity: integer);
   var
     tmpInvoiceItem: TInvoiceItem;
     tmpItem: TItem;
   begin
     if trim(itemDescription)='' then
       Exit;
   
     tmpItem:=fDatabase.GetItemFromDescription(trim(itemDescription));
     if not Assigned(tmpItem) then
       Exit;
   
     tmpInvoiceItem:=TInvoiceItem.Create;
     tmpInvoiceItem.ID:=tmpItem.ID;
     tmpInvoiceItem.InvoiceID:=fInvoice.ID;
     tmpInvoiceItem.UnitPrice:=tmpItem.Price;
     tmpInvoiceItem.Quantity:=quantity;
   
     fCurrentInvoiceItems.Add(tmpInvoiceItem);
   
   end;
   
   procedure TInvoiceModel.GetInvoiceItems(
     var itemsList: TObjectList<TInvoiceItem>);
   var
     tmpInvoiceItem: TInvoiceItem;
     i: integer;
   begin
     if not Assigned(itemsList) then
       Exit;
     itemsList.Clear;
     for i:=0 to fCurrentInvoiceItems.Count-1 do
     begin
       tmpInvoiceItem:=TInvoiceItem.Create;
       tmpInvoiceItem.ID:=fCurrentInvoiceItems.Items[i].ID;
       tmpInvoiceItem.InvoiceID:=fCurrentInvoiceItems.Items[i].InvoiceID;
       tmpInvoiceItem.ItemID:=fCurrentInvoiceItems.Items[i].ItemID;
       tmpInvoiceItem.UnitPrice:=fCurrentInvoiceItems.Items[i].UnitPrice;
       tmpInvoiceItem.Quantity:=fCurrentInvoiceItems.Items[i].Quantity;
   
       itemsList.Add(tmpInvoiceItem);
     end;
   end;
   
   procedure TInvoiceModel.GetInvoiceItemFromID(const itemID: Integer;
     var item: TItem);
   var
     tmpItem: TItem;
   begin
     if not Assigned(item) then
       Exit;
     tmpItem:=fDatabase.GetItemFromID(itemID);
     if Assigned(tmpItem) then
     begin
       item.ID:=tmpItem.ID;
       item.Description:=tmpItem.Description;
       item.Price:=tmpItem.Price
     end;
   end;
   
   procedure TInvoiceModel.CalculateInvoiceAmounts;
   var
     tmpItem: TInvoiceItem;
   begin
     fRunningBalance:=0.00;
     for tmpItem in fCurrentInvoiceItems do
       fRunningBalance:=fRunningBalance+(tmpItem.Quantity*tmpItem.UnitPrice);
   end;
   
   function TInvoiceModel.GetInvoiceRunningBalance: Currency;
   begin
     CalculateInvoiceAmounts;
     Result:=fRunningBalance;
   end;
   
   procedure TInvoiceModel.DeleteAllInvoiceItems;
   begin
     fCurrentInvoiceItems.Clear;
   end;
   
   function TInvoiceModel.GetNumberOfInvoiceItems: integer;
   begin
     result:=fCurrentInvoiceItems.Count;
   end;

The ViewModel

1. Add and develop the following procedures in the Model.Interface and ViewModel.Invoice units.

   unit Model.Interface;
   
   implementation
   
   ...
   
   type
     ...
     IInvoiceViewModelInterface = interface
       ...
       procedure AddInvoiceItem(const itemDescription: string; const quantity: integer);
       procedure DeleteAllInvoiceItems;
     end;
   
   implementation
   
   end.
   
   unit ViewModel.Invoice;
   
   interface
   ...
   
   implementation
   
   ...
   
   type
     TInvoiceViewModel = class(TInterfacedObject, IInvoiceViewModelInterface)
     private
       ...
     public
       ...
       procedure AddInvoiceItem(const itemDescription: string; const quantity: integer);
       procedure DeleteAllInvoiceItems;
     end;
   
   procedure TInvoiceViewModel.AddInvoiceItem(const itemDescription: string;
     const quantity: integer);
   begin
     fModel.AddInvoiceItem(itemDescription, quantity);
   end;
   
   procedure TInvoiceViewModel.DeleteAllInvoiceItems;
   begin
     fModel.DeleteAllInvoiceItems;
   end;

2. The ViewModel is doing all the required work to prepare the data into a form suitable for presentation. Suitable in this case means that the ViewModel should present the data to the View in such way that it could be shown in the string grid of the form. This illustrates the flexibility of the MVVM pattern; we use the ViewModel layer to adjust and manipulate the presentation state of the data according to the requirements of the View without the need to change the structural elements of the View (or the Model).

3. The string grid has five columns and receives strings. There are many ways to prepare data for this constellation. I will use a set of arrays that map to the columns of the string grid. Admittedly, this is not the best way to achieve this effect, but in this case, it is adequate as a demonstration of the functionality of the ViewModel.

4. Open Model.Declarations and add the following record.

   unit Model.Declarations;
   
   interface
   
   ...
   
   type
     ...
   
     TInvoiceItemsText = record
       DescriptionText,
       QuantityText,
       UnitPriceText,
       PriceText,
       IDText: array of string;
       InvoiceRunningBalance,
       InvoiceTotalBalance: string;
     end;
   
   implementation
   
   end.

5. Declare a property and a getter function in the Model.Interfaces unit and write the code for the procedure in ViewModel.Invoice.

   unit Model.Interfaces;
   
   interface
   
   ...
   
   type
     ...
     IInvoiceViewModelInterface = interface
       ...
       function GetInvoiceItemsText: TInvoiceItemsText;
   
       ...
       property InvoiceItemsText: TInvoiceItemsText read GetInvoiceItemsText;
     end;
   
   implementation
   
   end.
   
   unit ViewModel.Invoice;
   
   interface
   
   ...
   
   implementation
   
   uses
     ...
   
   type
     TInvoiceViewModel = class(TInterfacedObject, IInvoiceViewModelInterface)
     private
       ...
       function GetInvoiceItemsText: TInvoiceItemsText;
     public
       ...
     end;
   
   ...
   
   function TInvoiceViewModel.GetInvoiceItemsText: TInvoiceItemsText;
   var
     tmpRunning: Currency;
     tmpInvoiceItems: TObjectList<TInvoiceItem>;
     i, tmpLen: integer;
     tmpItem: TItem;
   begin
     tmpLen:=0;
     SetLength(fInvoiceItemsText.DescriptionText,tmpLen);
     SetLength(fInvoiceItemsText.QuantityText,tmpLen);
     SetLength(fInvoiceItemsText.UnitPriceText,tmpLen);
     SetLength(fInvoiceItemsText.PriceText,tmpLen);
     SetLength(fInvoiceItemsText.IDText, tmpLen);
     tmpRunning:=0.00;
   
       tmpInvoiceItems:=TObjectList<TInvoiceItem>.Create;
     fModel.GetInvoiceItems(tmpInvoiceItems);
     for i := 0 to tmpInvoiceItems.Count-1 do
     begin
       tmpLen:=Length(fInvoiceItemsText.DescriptionText)+1;
       SetLength(fInvoiceItemsText.DescriptionText,tmpLen);
       SetLength(fInvoiceItemsText.QuantityText,tmpLen);
       SetLength(fInvoiceItemsText.UnitPriceText,tmpLen);
       SetLength(fInvoiceItemsText.PriceText,tmpLen);
       SetLength(fInvoiceItemsText.IDText, tmpLen);
   
       tmpItem:=TItem.Create;
       fModel.GetInvoiceItemFromID(tmpInvoiceItems.Items[i].ID, tmpItem);
       fInvoiceItemsText.DescriptionText[tmpLen-1]:=tmpItem.Description;
       tmpItem.Free;
   
       fInvoiceItemsText.QuantityText[tmpLen-1]:=tmpInvoiceItems.Items[i].Quantity.ToString;
       fInvoiceItemsText.UnitPriceText[tmpLen-1]:=format('%10.2f',[tmpInvoiceItems.Items[i].UnitPrice]);
       fInvoiceItemsText.PriceText[tmpLen-1]:=
            format('%10.2f',[tmpInvoiceItems.Items[i].UnitPrice*tmpInvoiceItems.items[i].Quantity]);
       fInvoiceItemsText.IDText[tmpLen-1]:=tmpInvoiceItems.Items[i].ID.ToString;
     end;
     tmpInvoiceItems.Free;
   
     tmpRunning:=fModel.InvoiceRunningBalance;
   
     fInvoiceItemsText.InvoiceRunningBalance:=Format('%10.2f', [tmpRunning]);
     fInvoiceItemsText.InvoiceTotalBalance:=Format('%10.2f', [tmpRunning]);
   
     fPrintButtonEnabled:=fModel.NumberOfInvoiceItems > 0;
   
     Result:=fInvoiceItemsText;
   end;

6. The last procedure demonstrates the typical manipulation of data from the Model at the level of the ViewModel to represent the View logic. It also changes the status of the Print button to synchronize the View state with the state of the data.

The View

In the InvoiceForm, we need to retrieve the updated data from the ViewModel and present it in the form.

In View.InvoiceForm, declare a private variable called fInvoiceItemsText and add code to the click event of the Add button. We also need a procedure to update the items in the string grid (UpdateInvoiceGrid) and a procedure to update the total balances of the invoice (UpdateBalances). The following code (indicated in bold) also updates the SetViewModel procedure to call UpdateBalances in order to initialize the labels with the invoice’s balances.

The simplest way to update the grid with the invoice items is to call UpdateInvoiceGrid in the ButtonAddItemClick event. We are not going to follow this approach. Instead, we will ask the ViewModel to inform the View that there is a change to the invoice items and, therefore, it’s time to refresh the string grid.

In order to achieve this effect, we will use the ProSu framework developed in Chapter 4.

1. Add an action (actInvoiceItemsChanged) in Model.ProSu.InterfaceActions to signify the need to update the grid with the invoice items.

   unit Model.ProSu.InterfaceActions;
   
   interface
   
   type
     TInterfaceAction = (actUpdateTotalSalesFigure, actInvoiceItemsChanged);
     TInterfaceActions = set of TInterfaceAction;
   
   implementation
   
   end.

2. In View.InvoiceForm, declare a new procedure (NotificationFromProvider) that will be used to trigger actions from the message provider, register it with the provider, and write code to update the grid.

   

3. In ViewModel.Invoice, create a new procedure to send out messages to subscribers (SendNotification). Call it from the AddInvoiceItem and DeleteAllInvoiceItems, as follows.

   

Compile POSApp and execute it. Choose a customer from the popup box. Select an item and try to add it to the invoice. You should be able to see that the grid updates the items and balances.

You may argue that there is no need to create the notification loop to get an update of the invoice items’ grid in this View. We could very easily retrieve fViewModel.InvoiceItemsText in the View and publish the data. This is correct and it would work very well, too. The reason I chose to use ProSu here is because I wanted to show how the ViewModel (or the Model) could initiate communication.

For example, in a real application, we may have a situation in which item prices change in real-time due to availability and demand. Because of the way we constructed this application, we could easily implement this scenario. The ViewModel would send an actInvoiceItemsChanged to report on any updates even if the user was in the middle of issuing an invoice.

procedure TSalesInvoiceForm.PopupBoxCustomerChange(Sender: TObject);
begin

  fViewModel.GetCustomerDetails(PopupBoxCustomer.Text,fCustomerDetailsText);
  fViewModel.DeleteAllInvoiceItems;              
  PopupBoxItems.ItemIndex:=-1;              
  UpdateCustomerDetails;
end;