To add the hostname to your prompt, set the prompt variable in your ˜/.cshrc file as follows:

set prompt = "`hostname`% "

If a command other than hostname displays the machine name on your system, make the appropriate substitution.

To include the current directory name in your prompt, create a setprompt alias that sets the prompt using the current location. (setprompt uses the cwd variable, which always holds the pathname of your current working directory.) Then, alias the directory-changing commands (cd, pushd, popd ) so that they invoke setprompt. Add the following commands to your ˜/.cshrc file so that your prompt will be a % character preceded by the pathname of your current directory:

alias setprompt 'set prompt = "$cwd% "'
setprompt
alias cd 'cd !*;setprompt'
alias pushd 'pushd !*;setprompt'
alias popd 'popd !*;setprompt'

Note that setprompt is executed after it is defined. This is necessary to set the prompt to the proper initial value. Otherwise, the prompt would not be set until you changed directory for the first time.

If you prefer to display only the tail (last component) of the current directory’s pathname, change $cwd to $cwd:t in the definition of setprompt:

alias setprompt 'set prompt = "$cwd:t% "'

If you want both the hostname and the current directory displayed in your prompt, change the definition of setprompt to one of those shown below. Each definition displays the host name and a directory name, but the first definition displays the full pathname, whereas the second definition displays only the last component:

alias setprompt 'set prompt = "`hostname`:$cwd% "'
alias setprompt 'set prompt = "`hostname`:$cwd:t% "'

For the first definition, your prompt might look like the following example as you move around:

viper:/usr/staff/dubois% cd /usr/spool/mqueue
viper:/usr/spool/mqueue% cd ~/Projects/Programs/tokenscan
viper:/usr/staff/dubois/Projects/Programs/tokenscan%

The second definition produces a different prompt, like this:

viper:dubois% cd /usr/spool/mqueue
viper:mqueue% cd ~/Projects/Programs/tokenscan
viper:tokenscan%

alias setprompt 'set prompt = "$cwd% "'

alias setprompt 'set prompt = "-- $cwd --\
% "'

-- /usr/staff/dubois --
% cd /usr/spool/mqueue
-- /usr/spool/mqueue --
% cd ~/Projects/Programs/tokenscan
-- /usr/staff/dubois/Projects/Programs/tokenscan --
%

If you use tcsh, you have access to special prompt variable formatting sequences expressly intended for putting location information in the prompt string. Consequently, although the commands shown in the previous section do work for tcsh, you can achieve the same goal without messing around with a bunch of aliases.

Some useful sequences for displaying the directory or machine name are:

For example, to set your prompt so that it displays the current directory using ˜ notation, you need add only the following command to your ˜/.cshrc file:

set prompt = "%~% "

To set your prompt to host:dir%, where host is the first component of the hostname and dir is the current directory, use the following command:

set prompt = "%m:%~% "

If you want a multiple-line prompt, embed a newline in the prompt string. The previous set prompt command can be rewritten as follows:

set prompt = "-- %m:%~ --
% "

You can specify a window title as a command line argument when xterm starts up, or as a resource value in ˜/.Xdefaults, but neither method is satisfactory for changing the title on an ongoing basis as you move around the file system. However, xterm also understands certain control sequences, one of which sets the window title. This sequence can be sent to xterm at any time using echo, and the title can then be changed on demand. For BSD UNIX systems, the echo command to set the window titlebar to title is as follows:

echo -n "ESC]2;titleCTRL-G"

For versions of UNIX based on System V, the command is slightly different:

echo "ESC]2;titleCTRL-Gc"

Both commands suppress the newline that echo normally prints. (A newline is not part of the control sequence; unless you suppress it, xterm lets the newline pass through to your window, and you get an unwanted blank line.) The echo commands differ only in that BSD echo uses the –n flag to suppress the newline, whereas the System V echo uses c instead. You’ll need to choose the command that is appropriate for your system. If you don’t know which command to use, try the first and then, if you see –n in your window every time the titlebar changes, switch to the second command. The examples shown below use the BSD version; make the appropriate substitution as necessary.

To set up the shell to report your location in the titlebar, arrange to send xterm a title-change sequence whenever a directory change occurs. You can do so by aliasing cd, pushd, and popd in the same way that we set up the prompt-changing commands for csh earlier in the chapter.

Create a file in your home directory named .settitle that contains the commands shown below:

alias settitle 'echo -n "ESC]2;$cwdCTRL-G"'
settitle
alias cd 'cd !*;settitle'
alias pushd 'pushd !*;settitle'
alias popd 'popd !*;settitle'

To type literal ESC and CTRL–G characters into the file using your editor, you may need to precede them with CTRL–V.

You can vary the settitle alias definition if you like. To display only the last component of your directory in the title, change the $cwd to $cwd:t in the echo command, as shown below:

alias settitle 'echo -n "ESC]2;$cwd:tCTRL-G"'

Alternatively, you could display the directory stack. Being able to see the entire stack at a glance is helpful for using pushd +n and for using =n notation to refer to stack entries in command arguments. To display the directory stack, use the following command:

alias settitle 'echo -n "ESC]2;'dirs'CTRL-G"'

After you create .settitle, add the following line to your ˜/.cshrc file:

if (xterm =~ $TERM) source ~/.settitle

xterm sets the TERM environment variable to xterm, which allows the shell to tell whether or not it is running in an xterm window. If an xterm window is active the commands in .settitle are executed; otherwise, the commands are skipped (e.g., if you are using an ASCII terminal or are logging in through a modem from your microcomputer at home).

If you are using a terminal program similar to xterm, you may be able to set the window title by using a slightly modified version of the method outlined in the previous section. Some examples are discussed below. If the program you use to provide terminal windows is not covered, the principles may still be similar, although the details will vary. Consult your local documentation for more specific information.

#!/usr/local/bin/perl
printf "e&f0k%dD%s", length ($ARGV[0]), $ARGV[0] unless $#ARGV < 0;

alias settitle 'hptitle "$cwd"'
settitle
alias cd 'cd !*;settitle'
alias pushd 'pushd !*;settitle'
alias popd 'popd !*;settitle'

if (hpterm =~ $TERM) source ~/.settitle-hp

if (xterm =~ $TERM) then
    source ~/.settitle
else if (hpterm =~ $TERM) then
    source ~/.settitle-hp
endif

if (xterm =~ $TERM) source ~/.settitle
alias ncsa source ~/.settitle

If you have multiple accounts under different logins, you may find it useful to display the current username in your prompt or window title.

To display your name in the prompt with tcsh, just include %n in your prompt variable setting. The following example produces a prompt of name@host: dir%:

set prompt = "%n@%m:%~% "

To display the name in the prompt with csh, modify your setprompt alias to reference the appropriate environment variable (probably USER or LOGNAME, depending on what kind of system you have; we will use USER here). For example, to display the username and the last component of the directory name, use a definition of setprompt that looks like this:

alias setprompt 'set prompt = "${USER} $cwd:t% "'

To put the username in the window title, modify the settitle alias in your .settitle file. The following definition displays name@host followed by the directory stack:

alias settitle 'echo -n "ESC]2;${USER}@'hostname' 'dirs'CTRL-G"'

In tcsh, the hostname is available in the HOST environment variable. Referencing a variable is more efficient than running hostname, so the alias can be rewritten as follows:

alias settitle 'echo -n "ESC]2;${USER}@${HOST} `dirs`CTRL-G"'

The xterm control sequence to change a window’s icon text is similar to the one that sets the titlebar, as shown:

echo -n "ESC]1;stringCTRL-G"

Putting the echo command in an alias lets you set the icon text easily. The following seticon alias sets the icon to name@host :

alias seticon 'echo -n "ESC]1;${USER}@`hostname`CTRL-G"'

If you use tcsh, use the following seticon alias:

alias seticon 'echo -n "ESC]1;${USER}@${HOST}CTRL-G"'

If you want seticon to take an argument so that you can specify the title yourself, write the seticon alias, as shown:

alias seticon 'echo -n "ESC]1;!*CTRL-G"'