Code for the select example

// simple select
let internal q0 = query {
    for n in db.Course do
    select n.CourseName }

// general function to show the query result
let showResult query = query |> Seq.iter (printfn "%A")
showResult q0

Execution result

"Math"
"Physics"
"Biology"
"English"

Code for select with transform

let internal q1 = query {
    for n in db.Course.AsEnumerable() do
    select (sprintf "course name = %s" n.CourseName) }

showResult q1

Execution result

"course name = Math"
"course name = Physics"
"course name = Biology"
"course name = English"

let A = [0; 2; 4; 5; 6; 8; 9]
let B = [1; 3; 5; 7; 8]

query {
        for a in A do
        for b in B do
        where (a < b)
        select (a, b)
}
|> Seq.iter(fun (n, e) -> printfn "%d is less than %d" n e)

Execution result

0 is less than 1
0 is less than 3
0 is less than 5
0 is less than 7
0 is less than 8
2 is less than 3
2 is less than 5
2 is less than 7
2 is less than 8
4 is less than 5
4 is less than 7
4 is less than 8
5 is less than 7
5 is less than 8
6 is less than 7
6 is less than 8

Code for the where example

let internal q2 = query {
    for n in db.Student do
    where (n.Name.Length > 4)
    select n.Name }

showResult q2

Execution result

"Brent"
"Anita"
"Cathy"

The where filter function performed on the client side

let internal q3 = query {
    for n in db.Student do
    select n.Name }

// filter on client side
let q3_2 = q3 |> Seq.filter (fun n -> n.Length > 4)

showResult q3_2

Execution result

"Brent"
"Anita"
"Cathy"

let internal myQuery = query {
    for n in db.Student do
    select n.Name }

// filter on client side based on ID
let result =
    myQuery
    |> Seq.mapi (fun i n -> (i, n))
    |> Seq.filter (fun (i, n) -> i % 2 = 0)
    |> showResult

Execution result

(0, "Lisa")
(2, "Anita")
(4, "Cathy")
(6, "Zeoy")
(8, "John")

Code for the join example

let internal q5 = query {
    for student in db.Student do
    join course in db.CourseSelection on (student.StudentID = course.StudentID)
    select (course.CourseID, student.Name) }

showResult q5

Execution result

(3, "Anita")
(1, "Lisa")
(2, "Anita")
(2, "Brent")
(3, "Brent")
(1, "Anita")
(1, "Brent")

let q6  = query {
    for student in db.Student do
    groupJoin courseSelection in db.CourseSelection
        on (student.StudentID = courseSelection.StudentID) into g
    for courseSelection in g do
    join course in db.Course on (courseSelection.CourseID ?= course.CourseID)
    select (student.Name, course.CourseName) }

showResult q6

Execution result

("Anita", "Biology")
("Lisa", "Math")
("Anita", "Physics")
("Brent", "Physics")
("Brent", "Biology")
("Anita", "Math")
("Brent", "Math")

let internal q5 = query {
    for student in db.Student do
    leftOuterJoin selection in db.CourseSelection on
                   (student.StudentID =? selection.CourseID) into result
    for selection in result do
    select (student.Name, selection.Course.CourseName)
    }

showResult q5

Execution result

("Lisa", "Math")
("Lisa", "Math")
("Lisa", "Math")
("Brent", "Physics")
("Brent", "Physics")
("Anita", "Biology")
("Anita", "Biology")
("Ken", null)
("Cathy", null)
("Tom", null)
("Zeoy", null)
("Mark", null)
("John", null)

Sort code

let internal q4 = query {
    for n in db.Student do
    sortBy n.Name
    where (n.Name.Length > 4)
    select n.Name }

showResult q4

Execution result

"Anita"
"Brent"
"Cathy"

let internal q4_2 = query {
    for student in db.Student do
    sortBy student.Age.Value
    thenBy student.Name
    select (student.Name, student.Age) }

showResult q4_2

Execution result

("John", null)
("Anita", 20)
("Tom", 20)
("Lisa", 21)
("Zeoy", 21)
("Brent", 22)
("Cathy", 22)
("Ken", 22)
("Mark", 23)

let internal q4_3 = query {
    for student in db.Student do
    sortByNullableDescending student.Age
    thenBy student.Name
    select (student.Name, student.Age) }

showResult q4_3

Execution result

("Mark", 23)
("Brent", 22)
("Cathy", 22)
("Ken", 22)
("Lisa", 21)
("Zeoy", 21)
("Anita", 20)
("Tom", 20)
("John", null)

The code for a groupBy query

let internal q7 = query {
    for student in db.Student do
    groupBy student.Age into g
    select (g.Key, g.Count()) }

showResult q7

Execution result

(null, 1)
(20, 2)
(21, 2)
(22, 3)
(23, 1)

Code for using groupValBy

let internal q8 = query {
    for student in db.Student do
    groupValBy student.Name student.Age into g
    select (g, g.Key, g.Count()) }

showResult q8

Execution result

(seq ["John"], null, 1)
(seq ["Anita"; "Tom"], 20, 2)
(seq ["Lisa"; "Zeoy"], 21, 2)
(seq ["Brent"; "Ken"; "Cathy"], 22, 3)
(seq ["Mark"], 23, 1)

The code for the skip example

let internal q9 = query {
    for student in db.Student do
    sortByNullable student.Age
    skip 1
    select student.Name }

showResult q9

Execution result

"Tom"
"Anita"
"Lisa"
"Zeoy"
"Brent"
"Ken"
"Cathy"
"Mark"

The code for the take example

let internal q9 = query {
    for student in db.Student do
    sortByNullable student.Age
    take 3
    select student.Name }

showResult q9

Execution result

"John"
"Anita"
"Tom"

The code for the skipWhile example

open System
open System.Linq
open Microsoft.FSharp.Linq.NullableOperators

type Student() =
    member val ID = 0 with get, set
    member val Name = "" with get, set
    member val Age = Nullable(0) with get, set

let showResult query = query |> Seq.iter (printfn "%A")

let studentTable = [
        Student(ID = 1, Name = "Anita", Age = Nullable(22));
        Student(ID = 1, Name = "Kate", Age = Nullable(22))
        Student(ID = 1, Name = "Brent", Age = Nullable(23))
        Student(ID = 1, Name = "Lisa", Age = Nullable(23))
        Student(ID = 1, Name = "Mark", Age = Nullable(24)) ].AsQueryable()

// skip student whose age is less than 23
let internal q10 = query {
    for student in studentTable do
    sortByNullable student.Age
    skipWhile (student.Age ?< 23)
    select student.Name }

showResult q10

Execution result

"Brent"
"Lisa"
"Mark"

let internal q11 = query {
    for student in db.Student do
    sumByNullable student.Age }

printf "sum of student age = "
showResult [ q11 ]

let internal q12 = query {
    for student in db.Student do
    minByNullable student.Age }

printf "youngest student age = "
showResult [ q12 ]

let internal q13 = query {
    for student in db.Student do
    maxByNullable student.Age }

printf "oldest student age = "
showResult [ q13 ]

let internal q14 = query {
    for student in db.Student do
    averageByNullable (Microsoft.FSharp.Linq.Nullable.float student.Age) }

printf "average student age = "
showResult [ q14 ]

Execution result

sum of student age = 171
youngest student age = 20
oldest student age = 23
average student age = 21.375

// return first element
let internal q15 = query {
    for student in db.Student do
    select student.Name
    head }

showResult [ q15 ]

// get the first element; if there is no first element returned, returns default
value let internal q16 = query {
    for student in db.Student do
    select student.Name
    headOrDefault }

showResult [ q16 ]

open System
open System.Linq
open Microsoft.FSharp.Linq.NullableOperators

type Student() =
    member val ID = 0 with get, set
    member val Name = "" with get, set
    member val Age = Nullable(0) with get, set

let showResult query = query |> Seq.iter (printfn "%A")

let studentTable = [
        Student(ID = 1, Name = "Anita", Age = Nullable(22));
        Student(ID = 1, Name = "Kate", Age = Nullable(22))
        Student(ID = 1, Name = "Brent", Age = Nullable(23))
        Student(ID = 1, Name = "Lisa", Age = Nullable(23))
        Student(ID = 1, Name = "Mark", Age = Nullable(24)) ].AsQueryable()

// take the last student
let internal q15 = query {
    for student in studentTable do
    select student.Name
    last }

showResult [ q15 ]

// take the last student; if there is no last student, use default value
let internal q16 = query {
    for student in studentTable do
    select student.Name
    lastOrDefault }

showResult [ q16 ]

// return the 4th student in the list
let internal q17 = query {
    for student in studentTable do
    select student.Name
    nth 3 }

showResult [ q17 ]

Execution result

"Mark"
"Mark"
"Lisa"

let internal q17 = query {
    for student in db.Student do
    count }

showResult [ q17 ]

let internal q18 = query {
    for student in db.Student do
    join selection in db.CourseSelection on
        (student.StudentID = selection.StudentID)
    select student.Name
    distinct }

showResult q18

Execution result

"Anita"
"Brent"
"Lisa"

let internal q19 = query {
    for student in db.Student do
    select student.Name
    contains "Lisa" }

showResult [ q19 ]

let internal q20 = query {
    for student in db.Student do
    exists (student.Name = "Lisa") }

showResult [ q20 ]

let internal q21 = query {
    for student in db.Student do
    find (student.Age ?> 20) }

showResult [ q21.Name ]

Execution result

"Lisa"

let internal q22 = query {
    for student in db.Student do
    all (SqlClient.SqlMethods.Like(student.Name, "L%")) }

showResult [ q22 ]

let internal q23 = query {
    for student in db.Student do
    where (student.Name = "Lisa")
    exactlyOne }

showResult [ q23.Name ]

// define the type provider
type Demographics = Microsoft.FSharp.Data.TypeProviders.ODataService<ServiceUri =
    "https://api.datamarket.azure.com/Uk.Gov/TravelAdvisoryService/">

let ctx = Demographics.GetDataContext()

// set the credentials
ctx.Credentials <- System.Net.NetworkCredential(<liveID>, <id>)

// query the data source
let q = query {
    for n in ctx.BritishEmbassiesAndHighCommissions do
    select (n.Title, n.OfficeHours) }

// print out the result
q
|> Seq.iter (fun (address, _)-> printfn "%s" address)

Partial execution result

Australia, Hobart, British Honorary Consul
Australia, Adelaide, British Honorary Consul
Afghanistan, Kabul, British Embassy
Vietnam, Hanoi, British Council
Taiwan, Kaohsiung, British Council
Japan, Tokyo, British Council
Burma, Rangoon (Yangon), British Embassy
Australia, Canberra, Consular Section
New Zealand, Auckland, British Consulate-General
China, Guangzhou, British Consulate-General
Australia, Melbourne, British Consulate-General
Japan, Osaka, British Consulate-General
China, Shanghai, British Consulate-General
Australia, Brisbane, British Consulate
Australia, Perth, British Consulate
...

// define the type provider
type Demographics = Microsoft.FSharp.Data.TypeProviders.ODataService<ServiceUri =
    "https://api.datamarket.azure.com/Uk.Gov/TravelAdvisoryService/">

let ctx = Demographics.GetDataContext()

// set the credentials
ctx.Credentials <- System.Net.NetworkCredential(<liveID>, <id>)

// query the data source
let q = query {
    for n in ctx.BritishEmbassiesAndHighCommissions do
    //where (n.Title.Contains("United States"))  // where is not supported on server side
    select (n.Title, n.OfficeHours) }

// print out the result
q
|> Seq.filter (fun (title, _) -> title.Contains("China"))
|> Seq.iter (fun (title, _)-> printfn "%s" title)

Execution result

China, Guangzhou, British Consulate-General
China, Shanghai, British Consulate-General
China, Chongqing, British Consulate-General
China, Beijing, British Embassy
China, Beijing, British Embassy, Cultural & Education Section

// define the type provider
type Demographics = Microsoft.FSharp.Data.TypeProviders.ODataService<ServiceUri =
    "https://api.datamarket.azure.com/Uk.Gov/TravelAdvisoryService/">

let ctx = Demographics.GetDataContext()

// set the credentials
ctx.Credentials <- System.Net.NetworkCredential(<liveID>, <id>)

// query pages
let rec queryFunction (startPoint) =
    seq {
        // query the data source
        let q = query {
            for n in ctx.BritishEmbassiesAndHighCommissions do
            skip startPoint
            select (n.Title, n.OfficeHours) }
        let count = Seq.length q
        if count <> 0 then
            for item in q do
                yield item
            for item in queryFunction(startPoint + count) do
                yield item
    }

// print out the result
queryFunction(0)
|> Seq.filter (fun (title, _) -> title.Contains("United States"))
|> Seq.iter (fun (title, _)-> printfn "%s" title)

Execution result

United States, Denver, British Consulate-General
United States, Atlanta, British Consulate-General
United States, Boston, British Consulate-General
United States, Chicago, British Consulate-General
United States, Houston, British Consulate-General
United States, Los Angeles, British Consulate-General
United States, New York, British Consulate-General
United States, San Francisco, British Consulate-General
United States, Miami, British Consulate-General
United States, Orlando, British Consulate
United States, Washington, British Embassy
United States, Anchorage, British Honorary Consulate
United States, Nashville, British Honorary Consulate
United States, New Orleans, British Honorary Consulate
United States, Philadelphia, British Honorary Consulate
United States, Phoenix, British Honorary Consulate
United States, Pittsburgh, British Honorary Consulate
United States, Salt Lake City, British Honorary Consulate
United States, Charlotte, British Honorary Consulate
United States, Michigan, British Honorary Consulate
United States, Minnesota, British Honorary Consulate
United States, Ohio, British Honorary Consulate

open System.Linq

// define a translate function by taking an English sentence and translating it to
Chinese let translate txt =
    let serviceRootUri =
        new System.Uri("https://api.datamarket.azure.com/Bing/MicrosoftTranslator/")

    // the account key is the same as in the previous section
    let accountKey = <id>

    // create a translator container that is defined in the proxy class
    let tc = Microsoft.TranslatorContainer(serviceRootUri)
    tc.Credentials <- new System.Net.NetworkCredential(accountKey, accountKey)

    //translate from English(en) to Chinese (zh-CHS)
    let translationQuery = tc.Translate(txt, "zh-CHS", "en")
    let translationResult = translationQuery.Execute().ToList().FirstOrDefault()

    // if there is no translation result, something went wrong so return empty string
    if (translationResult = null) then
        System.String.Empty
    else
        translationResult.Text

// define the type provider
type Demographics = Microsoft.FSharp.Data.TypeProviders.ODataService<ServiceUri =
    "https://api.datamarket.azure.com/Uk.Gov/TravelAdvisoryService/">
let ctx = Demographics.GetDataContext()

// set the credentials
ctx.Credentials <- System.Net.NetworkCredential(<liveID>, <id>)

//get latest news
let latestNews = query {
    for n in ctx.LatestTravelNewsFromFco do
    select (n.Title, n.Summary)
}

latestNews
|> Seq.map fst           // only leave title to translate
|> Seq.map translate   //translate from English to Chinese
|> Seq.iter (fun n -> printfn "%s" n)

Execution result

恶劣天气影响整个欧洲的旅行
下个星期为欧洲足球赛事旅游忠告
西班牙机场中断
象牙海岸的旅游建议的变化
玻利维亚旅游忠告-鲁雷纳瓦克在封锁
在欧洲旅行的中断
澳大利亚旅游忠告-东澳大利亚的水浸
美国旅游忠告-暴雪条件
旅游忠告-尤文图斯 v 曼城
希腊旅游忠告-工业行动
...